feat: add frr_exporter class

- add frr exporter to all nodes running frr
2025-08-03 15:38:13 +10:00
parent 53fabc923b
commit 9deeacce22
10 changed files with 140 additions and 0 deletions
@@ -0,0 +1,68 @@
+class exporters::frr_exporter (
+  Boolean $enable         = false,
+  String  $user           = 'frr_exporter',
+  String  $group          = 'frr_exporter',
+  Boolean $manage_user    = true,
+  Boolean $manage_service = true,
+  Stdlib::Port $port      = 9342,
+  Stdlib::Absolutepath $exec_path  = '/usr/bin/frr_exporter',
+  Stdlib::Absolutepath $socket_dir = '/var/run/frr',
+){
+
+  if $enable {
+
+    # install required package
+    package {'frr_exporter':
+      ensure => installed,
+    }
+
+    # manage the user/group
+    if $manage_user {
+      group { $group:
+        ensure => present,
+      }
+
+      user { $user:
+        ensure     => present,
+        shell      => '/usr/sbin/nologin',
+        groups     => [$group, 'frrvty'],
+        managehome => true,
+      }
+    }
+
+    # manage the systemd service
+    if $manage_service {
+
+      # Use these in notifications or file resources
+      systemd::unit_file { 'frr_exporter.service':
+        content   => template('exporters/frr_exporter.service.erb'),
+        enable    => true,
+        active    => true,
+        subscribe => Package['frr_exporter'],
+      }
+    }
+
+    # manage consul service
+    consul::service { 'frr_exporter':
+      service_name => 'frr_exporter',
+      address      => $facts['networking']['ip'],
+      port         => $port,
+      tags         => [
+        'metrics',
+        'metrics_scheme=http',
+        'metrics_job=frr',
+      ],
+      checks       => [
+        {
+          id              => 'frr_exporter_http_check',
+          name            => 'frr_exporter HTTP Check',
+          http            => "http://${facts['networking']['fqdn']}:${port}/metrics",
+          method          => 'GET',
+          tls_skip_verify => true,
+          interval        => '10s',
+          timeout         => '1s',
+        },
+      ],
+    }
+  }
+}
@@ -0,0 +1,15 @@
+[Unit]
+Description=Prometheus frr_exporter
+Wants=network-online.target
+After=network-online.target
+
+[Service]
+User=<%= @user %>
+Group=<%= @group %>
+ExecStart=<%= @exec_path %> --frr.socket.dir-path="<%= @socket_dir %>"
+ExecReload=/bin/kill -HUP $MAINPID
+KillMode=process
+Restart=always
+
+[Install]
+WantedBy=multi-user.target