#!ipxe
dhcp

# Some menu defaults
set menu-timeout 5000
set submenu-timeout ${menu-timeout}
set menu-default cobbler

:start
menu iPXE boot menu
item --gap --                   ----------------------------- Cobbler ------------------------------------
item            cobbler                 Cobbler (kickstart or boot from disk)
item --gap --                   ------------------------- Advanced options -------------------------------
item --key s    shell                   Drop to iPXE shell
item --key r    reboot                  Reboot
item
item --key x    exit                    Exit iPXE and continue BIOS boot
choose --timeout ${menu-timeout} --default ${menu-default} selected || goto cancel
set menu-timeout 0
goto ${selected}

:cancel
echo You cancelled the menu, dropping you to a shell

:no_system
echo No system configuration found for MAC address ${mac}
goto exit

:shell
echo Type 'exit' to get the back to the menu
shell
set menu-timeout 0
set submenu-timeout 0
goto start

:reboot
reboot

:exit
exit

###
### Custom menu entries
###

:cobbler
chain --autofree http://${next-server}/cblr/svc/op/gpxe/mac/${net0/mac} || goto no_system