# instsall radarr
class radarr::install (
  $packages      = $radarr::packages,
  $user          = $radarr::user,
  $group         = $radarr::group,
  $manage_group  = $radarr::manage_group,
  $base_path     = $radarr::base_path,
  $install_path  = $radarr::install_path,
  $config_folder = $radarr::config_folder,
  $app_folder    = $radarr::app_folder,
  $archive_name  = $radarr::archive_name,
  $archive_url   = $radarr::archive_url,
  $executable    = $radarr::executable,
) {

  $_packages = $packages ? {
    Array   => true,
    default => false,
  }

  if $_packages {
    ensure_packages($packages, {ensure => 'installed'})
  }

  if $manage_group {
    group { $group:
      ensure => present,
    }
  }

  user { $user:
    ensure     => present,
    shell      => '/sbin/nologin',
    groups     => $group,
    managehome => true,
  }

  file { [ $base_path, $install_path, $config_folder, $app_folder ]:
    ensure => directory,
    owner  => $user,
    group  => $group,
  }

  archive { $archive_name:
    path         => "/tmp/${archive_name}",
    source       => "${archive_url}${archive_name}",
    extract      => true,
    extract_path => $install_path,
    creates      => "${install_path}/${executable}",
    cleanup      => true,
    require      => File[$install_path],
    user         => $user,
    group        => $group,
    notify       => Exec['move_radarr_files'],
  }

  exec { 'move_radarr_files':
    command => "/usr/bin/mv ${install_path}/Radarr/* ${install_path}",
    creates => "${install_path}/${executable}",
  }
}