Ben Vincent
7f03bc5c76
- add certmanager script and config.yaml file - install into pyenv for certmanager - deploy to puppet-masters only
76 lines
2.1 KiB
Puppet
76 lines
2.1 KiB
Puppet
# profiles::helpers::certmanager
|
|
#
|
|
# wrapper class for python, pip and venv
|
|
class profiles::helpers::certmanager (
|
|
String $script_name = 'certmanager',
|
|
Stdlib::AbsolutePath $base_path = "/opt/${script_name}",
|
|
Stdlib::AbsolutePath $venv_path = "${base_path}/venv",
|
|
Stdlib::AbsolutePath $config_path = "${base_path}/config.yaml",
|
|
Hash $vault_config = {},
|
|
String $owner = 'root',
|
|
String $group = 'root',
|
|
Boolean $systempkgs = false,
|
|
String $version = 'system',
|
|
Array[String[1]] $packages = ['requests', 'pyyaml'],
|
|
){
|
|
|
|
if $::facts['python3_version'] {
|
|
|
|
$python_version = $version ? {
|
|
'system' => $::facts['python3_version'],
|
|
default => $version,
|
|
}
|
|
|
|
# ensure the base_path exists
|
|
file { $base_path:
|
|
ensure => directory,
|
|
mode => '0755',
|
|
owner => $owner,
|
|
group => $group,
|
|
}
|
|
|
|
# create a venv
|
|
python::pyvenv { $venv_path :
|
|
ensure => present,
|
|
version => $python_version,
|
|
systempkgs => $systempkgs,
|
|
venv_dir => $venv_path,
|
|
owner => $owner,
|
|
group => $group,
|
|
require => File[$base_path],
|
|
}
|
|
|
|
# install the required pip packages
|
|
$packages.each |String $package| {
|
|
python::pip { "${venv_path}_${package}":
|
|
ensure => present,
|
|
pkgname => $package,
|
|
virtualenv => $venv_path,
|
|
}
|
|
}
|
|
|
|
# create the script from a template
|
|
file { "${base_path}/${script_name}":
|
|
ensure => file,
|
|
mode => '0755',
|
|
content => template("profiles/helpers/${script_name}.erb"),
|
|
require => Python::Pyvenv[$venv_path],
|
|
}
|
|
|
|
# create the config from a template
|
|
file { $config_path:
|
|
ensure => file,
|
|
mode => '0600',
|
|
content => Sensitive(template("profiles/helpers/${script_name}_config.yaml.erb")),
|
|
require => Python::Pyvenv[$venv_path],
|
|
}
|
|
|
|
# create symbolic link in $PATH
|
|
file { "/usr/local/bin/${script_name}":
|
|
ensure => 'link',
|
|
target => "${base_path}/${script_name}",
|
|
require => File["${base_path}/${script_name}"],
|
|
}
|
|
}
|
|
}
|